Ir al contenido principal

Colores Multiples

literalmente este codigo es un DOLORde

Bueno el codigo es este
 Literal mente ocupa 1152x768


Aqui esta:
@echo off
setlocal

call :initColorPrint

call :colorPrint 0a "a"
call :colorPrint 0b "b"
set "txt=^" & call :colorPrintVar 0c txt
call :colorPrint 0d "<"
call :colorPrint 0e ">"
call :colorPrint 0f "&"
call :colorPrint 1a "|"
call :colorPrint 1b " "
call :colorPrint 1c "%%%%"
call :colorPrint 1d ^"""
call :colorPrint 1e "*"
call :colorPrint 1f "?"
call :colorPrint 2a "!"
call :colorPrint 2b "."
call :colorPrint 2c ".."
call :colorPrint 2d "/"
call :colorPrint 2e "\"
call :colorPrint 2f "q:" /n
echo(
set complex="c:\hello world!/.\..\\a//^<%%>&|!" /^^^<%%^>^&^|!\
call :colorPrintVar 74 complex /n

call :cleanupColorPrint

exit /b

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:colorPrint Color  Str  [/n]
setlocal
set "str=%~2"
call :colorPrintVar %1 str %3
exit /b

:colorPrintVar  Color  StrVar  [/n]
if not defined %~2 exit /b
setlocal enableDelayedExpansion
set "str=a%DEL%!%~2:\=a%DEL%\..\%DEL%%DEL%%DEL%!"
set "str=!str:/=a%DEL%/..\%DEL%%DEL%%DEL%!"
set "str=!str:"=\"!"
pushd "%temp%"
findstr /p /A:%1 "." "!str!\..\x" nul
if /i "%~3"=="/n" echo(
exit /b

:initColorPrint
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do set "DEL=%%a"
<nul >"%temp%\x" set /p "=%DEL%%DEL%%DEL%%DEL%%DEL%%DEL%.%DEL%"
exit /b

:cleanupColorPrint
del "%temp%\x"
exit /b

Los call :colorprint son los echos con diferentes colores
  
Pues ustedes creeran que
es una parte como "Codminal" digo yo



Codminal

un codigo madre (Codigo usado por casi todos los comandos) Sacado de Terminal


Pero no lo es, cada comando en cualquier parte tiene que tener su Propio Codminal!
Un dolor de cabesa.

Comentarios

Entradas más populares de este blog

Pause >nul|set /p =Pausa Con Otro Nombre

Todos Conosemos nuesto C:/Windows/System32/> pause pERO sI oh... Bloque DE CAPS Pero si añadimos >nul? LOL NO HAY NADA XDDDDD pero cuando grababa para ensñarles que no es mentira paso... bueno aqui les va el video puse un temporisador para que sepan que es pause y no algo que dure por segundos

Add-Ons?

Hola Gatunos, Reciente mente meti a my carpeta SYSTEM32  un bat llamado rainbow y cuando entree la palabra "rainbow" ocurrio esto :O real mente no me lo espere...